Z Space Blog - Vim

Vim Author Bram Moolenaar Has Died

2023-08-05T12:38:00-07:00

I woke up to a huge gut punch this morning: Bram Moolenaar, legendary author of the Vim text editor, has passed away. Given the occasion, I want to express some thoughts regarding both Bram and his software. Without his work, I'm not sure I would be the same person.

How I found Vim

On a wintry Wisconsin night in 2004, I was looking for better, more customizable software. I was a teenager, learning about alternative OSes and losing patience with Windows every passing day. I had started getting more serious about learning web development, and began trying different text editors, to see what was to my taste. As we all know, Notepad on Windows is NOT sufficient for programming.

On this path of discovering text editors, I stumbled across all sorts of things, from UltraEdit to metapad, Notepad++, gedit, AceHTML, Emacs, and eventually I found this free software called "vim", but it came with some newbie-friendly settings, called Cream. (I was surprised to see it's still around!) One thing that stood out to me about Vim, at the time, was the fact I didn't have to enter some weird licensing scheme. I didn't have to pay to unlock features, and the big thing was -- if I wanted to help, I could donate to a charity that actually helped people! That stuck with me, morally. "Huh, all these companies are making software for profit, but this guy from Europe just wants me to help some less fortunate people. That's awesome."

I would not realize it until years later, but discovering Vim was a key step in my journey to libre software and GNU/Linux. Had I not been looking for a free, customizable text editor to do what I wanted, it may have delayed or slowed my introduction to that world.

How I Use Vim Today

These days, I keep a small group of plugins (mostly things like fugitive, tabular, sparkup, and some syntax stuff), a hefty vimrc with keyboard layout switching capabilities, and there's almost always a Vim process open on my machines. It earned a place as my favorite piece of software when I learned how easy it is to extend its behavior. No other piece of software evolves with me and my skill level like Vim does.

I love Vim's documentation system the most, I think. If there's anything I don't know about Vim, I can consult :help and get answers immediately. For anything else, there is a broad community of fellow text-heads out there, who might even have saved a fricken macro for the task you're trying to achieve.

Each time I learn something new about Vim, I feel like I've unlocked a new ability, or added a new text wrangling tool to my belt. This, in turn, improves my ability to manipulate text and makes the editing experience that much better.

The Future of Vim

It seems that Bram had tapped a successor, in some way, before he died, but the state of things with the Vim project seem to indicate his death was not expected, per se, though he had been ill for a few months prior to his death. It is sad to see another one of the "original breed" of FOSS hackers pass on. It stands as a reminder of how little time we really have on this rock, and the importance of choosing goals that one can look back on with pride. I hope that the new primary author and maintainer, Christian Brabandt, leads the project with the same core values that Bram did. Christian expresses his thoughts in the Google Groups thread.

Vim is the reason I discovered the Free Software movement. It's the software that I use most in my day-to-day computing. How strange, that a journey for a good text editor led to me discovering an entire social movement of hackers that I still hover around to this day, nearly 20 years later. Thank you, Bram, for bringing joy to my computing and rewarding every new morsel of knowledge I gain about this beautiful tool.

I have nothing but condolences for the Moolenaar family in their time of grieving. I hope their hearts are made lighter by the worldwide celebration of Bram's wonderful work, and the many testimonies people are publishing today which show how influential he was. We are all privileged to have received his work.

Please consider donating to ICCF Holland if you wish to leave a token of appreciation for Bram. It's what he would ask for.

Easy diffing with Vim

2018-10-13T00:00:00-07:00

Vim has good support for showing the differences between two (or three) files with either the vimdiff command or setting up a diff session manually. This often requires opening the files in their own window panes, then using :diffthis in all the relevant files. If you're in the middle of an editing session, stopping to set up this diff session can cause you to lose focus. I wrote a function in my vimrc that automates this process, so the user can focus on making decisions instead of building their UI or some other flow-breaking process.

" Function: BufDiff
" Author: zlg <zlg+viml@zlg.space>
" Date: 2018-10-12
" License: GNU GPL, version 3 <https://gnu.org/licenses/gpl-3.0.html>
" Description: Open a new tab page with two or three buffers and enter diff mode.
" Long Description:
" BufDiff accepts two or three buffer arguments and opens a new tab page to
" work with them in diff mode. This ensures that your existing window and
" buffer layout is preserved while providing an easy way to enter a diff
" session. The arguments can be any argument that can also be passed to
" the ":buffer" Ex-command, including partial filenames (if quoted).
function! BufDiff(buf1, buf2, ...)
    let fname = substitute(expand("<sfile>"), "^function ", "", "")
    if a:0 > 1
        echohl ErrorMsg
        echomsg l:fname . ": This function accepts a maximum of three arguments."
        echohl None
        return
    endif

    " Check for a third buffer, which will default to zero if not present
    let a:buf3 = get(a:, 1, 0)

    if !bufexists(a:buf1) || !bufexists(a:buf2) || (a:0 == 1 && !bufexists(a:buf3))
        echohl ErrorMsg
        echomsg l:fname . ": One or more buffer number(s) not found!"
        echohl None
        return
    else
        tabnew
        exe ":buffer " . a:buf1
        diffthis
        vsplit
        exe ":buffer " . a:buf2
        diffthis
        if a:buf3
            vsplit
            exe ":buffer " . a:buf3
            diffthis
        endif
        return
    endif
endfunction

BufDiff() allows me to reference two or three open buffers and put them into a separate diff session via a tab page. When I'm done working with the diff session, I can :tabc to close the tabpage and my original session (from the prior tabpage) is still intact, ready for me to continue work.

Using it is simple. Let's say you invoke vim with vim foo.txt bar.txt. You'll end up in Vim with the contents of foo.txt (or an empty buffer ready for writing to said file), with bar.txt in a second buffer. If I do :call BufDiff(1,2), the new tabpage will come up and compare the two files. I could also use :call BufDiff("foo", "bar"), since the arguments get sent to the :buffer Ex-command.

The primary limitation of BufDiff is you need the files you want to compare to be present in the buffer list already. Many people begin working on their projects with a one-liner that opens all the relevant source files, so it's a limitation that I think is bearable.

If you use this function, let me know how it worked out for you! Improvements and suggestions are also welcome.

Shoutout to tockitj from Freenode's #vim channel for the inspiration.

Counting Lines of Code in Vim

2014-02-10T01:35:00-08:00

Vim is a wonderfully extensible text editor. I use it to work with all sorts of text. While I was browsing reddit, I saw a thread asking for a way to prevent :number from counting blank lines. I checked it out to see if there were any cool answers. None of what I saw were adequate. For instance, :%s/\S\+//n makes every match highlight, clobbering the last text that was searched for. I figured it was time for me to learn a little more about Vimscript, and so I wrote a function that will tell you how many actual lines of code are in your file:

" Count the number of source lines in a file
function! <SID>CountCodeLines()
    let code_count = 0
    for line in getbufline("%", 1, "$")
        if (len(line) > 0 && match(line, '\S\+') > -1)
            if (s:IsCommentLine(line) == 1)
                continue
            endif
            let code_count += 1
        endif
    endfor
    echo code_count . ' lines of code.'
endfunction

" To be used with CountCodeLines()
function! s:IsCommentLine(line)
    let l:comtypes = []
    let l:comlist = split(&comments, ',')
    for i in comlist
        let l:type = split(i, ':')
        if len(type) > 1
            let l:opt = type[1]
        else
            let l:opt = type[0]
        endif
        call add(comtypes, opt)
    endfor
    let i = 0
    while i < len(comtypes)
        if match(a:line, '^\s*' . escape(comtypes[i], '/*')) > -1
            return 1
        endif
        let i += 1
    endwhile
    return 0
endfunction

Put that in your ~/.vimrc or another similar location and have at it! I chose to map it to <leader>c with:

nnoremap <leader>c :call <SID>CountCodeLines()<CR>

I'm releasing these functions under the WTFPL to contribute another mini-feature to Vim and the free, open source software community. It was a fun (if slightly aggravating) exercise in Vimscript.